cd posts
for f in ../old_posts/*.md
do
    base=$(basename "$f" ".md")
    mkdir "${base}"
    pandoc -f markdown+yaml_metadata_block -t org --template ../custom_org_pandoc_template -o "${base}"/index.org --lua-filter=../date-format.lua "$f"
done

  -- source: https://stackoverflow.com/questions/72658259/how-do-i-format-date-in-pandoc-html-output
function Meta(meta)
  if meta.date then
    local format = "(%d+)-(%d+)-(%d+)T(%d+):(%d+):(%d+).*"
    local y, m, d = pandoc.utils.stringify(meta.date):match(format)
    local date = os.time({
      year = y,
      month = m,
      day = d,
    })
    local date_string = os.date("%Y-%m-%d %a %H:%M", date)

    meta.date = pandoc.Str(date_string)
    return meta
  end
end

(package-initialize)
(require 'ox-publish)
;own variables
(setq samd/posts-publish-directory "blog/"
      samd/asset-directory-name "static/") ;trailing slash is important
;settings source: https://orgmode.org/manual/Publishing-options.html
;;Generic Properties
(setq user-full-name "Your Name"
      org-export-default-language "en"
      org-export-headline-levels 5 ;Instead of 3, set the maximum headline level to 5. This matches the HTML standard of having six headline levels, when counting the document title as the first, leaving five. source: https://jeffkreeftmeijer.com/emacs-configuration/#org
      org-export-preserve-breaks nil ;default. Do not preserve line breaks in text 
      org-export-with-section-numbers nil
      org-export-timestamp-file nil ;Non-nil inserts an html comment with the timestamp the file was create
      org-export-with-author nil 
      org-export-with-creator nil
      org-export-with-broken-links nil 
      org-export-with-drawers nil
      org-export-with-email nil
      org-export-with-smart-quotes t
      org-export-with-special-strings t
      org-export-with-statistics-cookies nil
      org-export-with-sub-superscripts nil
      org-export-with-toc nil
      org-export-with-tags t 
      org-export-with-title t ;nil ;do not export title into a hader element. This allows us to do so in the preamble (and thus group title and additional data in the same <header> tag
      )
;;HTML specific properties
(setq 
      org-html-doctype "html5"
      org-html-container-element "section" ;used for wrapping top-level blocks (in this case only applies to pages). ;gets applied around all (level 1?) headings in org file
      org-html-html5-fancy t ;use new html5 elements
      org-html-divs '((preamble  "header" "preamble")
                      (content   "main" "content")
                      (postamble "footer" "postamble"))
      org-html-head "<link rel=\"stylesheet\" type=\"text/css\" href=\"/css/sp.css\" /><link rel=\"shortcut icon\" href=\"http://sam-d.com/favicon.ico\">"
      org-html-head-include-default-style nil
      org-html-head-include-scripts nil
      org-html-inline-images t
      org-html-with-latex nil ;set to t for MathJax  
      org-html-validation-link nil
      org-html-postamble "<span class=\"hr\"></span><footer style=\"text-align:center\">
        All content licensed <a href=\"https://creativecommons.org/licenses/by/4.0/\">CC-BY</a> unless otherwise indicated except for any pictures which are © of the author (%a)<br /><a href=/impressum.html>Impressum</a> <a href=/datenschutz.html>Datenschutz</a></footer>" ;global footer
      org-html-preamble "<h1 style=\"text-align:center\">Your title or logo</h1><span class=\"hr\"></span><nav><ul><li><a href=\"/\">Home</a></li><li><a href=\"/#about\">About</a></li><li><a href=\"/#projects\">Projects</a></li><li><a href=\"/#blog\">Blog</a></li></ul></nav>" 
      )

;the code below ensures clean URLs
;source: https://diego.codes/post/blogging-with-org/
(defun filter-local-links (link backend info)
  "Filter that converts all the /index.html links to /"
  (if (org-export-derived-backend-p backend 'html)
          (replace-regexp-in-string "/index.html" "/" link)))

(defun samd/remove-assets-from-links (link backend info)
  "Filter that removes the asset directory from the link. This allows linking to assets by file system path and thus allows to e.g. inline images"
  (if (org-export-derived-backend-p backend 'html)
      (replace-regexp-in-string samd/asset-directory-name "" link)))

(defun samd/remove-posts/pages-from-links (link backend info)
  "Filter that removes the post or pages directory from the link.
This allows linking between posts and pages and vice-versa"
  (if (org-export-derived-backend-p backend 'html)
      (replace-regexp-in-string "pages/" "" (replace-regexp-in-string "posts/" "blog/" link))))

(defun samd/add-author-timestamp (content backend info)
  "Filter to add Author and timestamp information into the header tag containing the post title"
  (if (and (org-export-derived-backend-p backend 'html) (org-export-get-date info ))
      (let ((timestamp (org-export-get-date info "%Y-%m-%dT%T"))
            (timestring (org-export-get-date info "%B %e, %Y")))
        (replace-regexp-in-string "\\(<main.*\\(\n.*\\)*\\)</header>" (concat "\\1 <p class=\"info\">Written by "
                                            (org-export-data (plist-get info :author) info)
                                            " on <time datetime=\"" (org-export-data timestamp info) "\">" (org-export-data timestring info) "</time></p></header>")
                                  content))))
;; Do not forget to add the functions to the list!
(add-to-list 'org-export-filter-link-functions 'filter-local-links)
(add-to-list 'org-export-filter-link-functions 'samd/remove-assets-from-links)
(add-to-list 'org-export-filter-link-functions 'samd/remove-posts/pages-from-links)
(add-to-list 'org-export-filter-final-output-functions 'samd/add-author-timestamp)

(defun samd/org-publish-sitemap-as-list (entry style project)
  "copy of default function, changed to add path to blog in the link and date at the end of the entry"
  (cond ((not (directory-name-p entry))
         (format "[[file:%s/%s][%s]] - %s"
                 (concat "../" samd/posts-publish-directory)
                 entry
                 (org-publish-find-title entry project)
                 (format-time-string "%b %e, %Y" (org-publish-find-date entry project))))
        ((eq style 'tree)
         ;; Return only last subdir.
         (file-name-nondirectory (directory-file-name entry)))
        (t entry)))

(setq org-publish-project-alist
      `(("posts"
         :base-directory "./posts"
         :base-extension "org" ;default value
         :publishing-directory ,(concat "public/" samd/posts-publish-directory)
         :recursive t ;required because posts in subfolders
         :auto-sitemap t
         :sitemap-filename "index.inc"
         :sitemap-title ""
         :sitemap-style list
         :sitemap-format-entry samd/org-publish-sitemap-as-list
         :sitemap-sort-files anti-chronologically
         :publishing-function org-html-publish-to-html)
        ("static"
         :base-directory ,(concat "./" samd/asset-directory-name)
         :base-extension any
         :publishing-directory "public/"
         :publishing-function org-publish-attachment
         :recursive t)
        ("pages"
         :base-directory "./pages"
         :base-extension "org"
         :recursive t
         :exclude ,(rx (seq line-start "index.org")); exclude the homepage, e.g. top-level index.org file
         :publishing-directory "./public")
        ;we want to overwrite the html-preamble for the homepage only, so we exclude all other pages by using a file extension that does not exist 
        ("homepage"
         :base-directory "./pages"
         :base-extension "doesnotexist"
         :publishing-directory "./public"
         :include ("index.org")
         :html-preamble ""))) ;override preamble here!

grep -e loc sitemap.xml | sed 's|<loc>\(.*\)<\/loc>$|\1|g' | xargs -I {} curl -s -o /dev/null -w "%{http_code} %{url_effective}\n" {} | grep -v 200